ANEW --USES--  DECIMAL                    \  Wil Baden  2002-07-21

\  *******************************************************************
\  *                                                                 *
\  *  Wil Baden  2002-07-21                                          *
\  *                                                                 *
\  *     USES:                                                       *
\  *                                                                 *
\  *  Iterated interpretation with single words.                     *
\  *                                                                 *
\  *******************************************************************

\  USES:                     ( "code<eol> ... ... ... -->" -- )
\     Evaluate _code_ for each white-space delimited word down to
\     `etc`.

\     The stack diagram for _code_ is ( k*x str len -- k*x ).
\     where ( str len) is the string descriptor of the word.

\  Uses `#EOL-CHAR` and `Next-Word` from ToolBelt.

    256 BUFFER:  Iterated-Action

: USES:                     ( "code<eol> ... ... ... -->" -- )
    #EOL-CHAR PARSE  Iterated-Action PLACE ( )
    BEGIN
        Next-Word         ( str len)
    dup WHILE
        S" etc" 2over COMPARE
    WHILE
        Iterated-Action COUNT EVALUATE ( )
    REPEAT THEN
    2DROP ; IMMEDIATE
    
\  Thanks to Marcel Hendrix.

\\   //   \\   //   \\   //   \\   //   \\   //   \\   //   \\   //   \\